korrect: init at 0.1.3 (#403417)

maintainers/maintainer-list.nix

@@ -6870,6 +6870,12 @@
     githubId = 7389000;
     name = "Dominic Wrege";
   };
+  dwt = {
+    email = "spamfaenger@gmx.de";
+    github = "dwt";
+    githubId = 57199;
+    name = "Martin Häcker";
+  };
   dxf = {
     email = "dingxiangfei2009@gmail.com";
     github = "dingxiangfei2009";

pkgs/by-name/ko/korrect/package.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchCrate,
+  rustPlatform,
+  installShellFiles,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "korrect";
+  version = "0.1.3";
+
+  src = fetchCrate {
+    inherit (finalAttrs) pname version;
+    hash = "sha256-U363YI1CQg7KAUtzN2GPm4fNnD3TgJy+6hT/3JZ8e2s=";
+  };
+  cargoHash = "sha256-WP03Gv+Nai834xurVzdzV4uLA8fT/lbdu4zGWUgDKJo=";
+
+  passthru.updateScript = nix-update-script { };
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd ${finalAttrs.meta.mainProgram} \
+      --bash <($out/bin/${finalAttrs.meta.mainProgram} completions bash) \
+      --fish <($out/bin/${finalAttrs.meta.mainProgram} completions fish) \
+      --zsh <($out/bin/${finalAttrs.meta.mainProgram} completions zsh)
+  '';
+
+  meta = {
+    description = "Kubectl version managing shim that invokes the correct kubectl version";
+    homepage = "https://gitlab.com/cromulentbanana/korrect";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.dwt ];
+    mainProgram = "korrect";
+  };
+})